mirror of
https://git.proxmox.com/git/mirror_zfs.git
synced 2024-11-17 10:01:01 +03:00
ff5587d651
The getrawmonotonic() and getrawmonotonic64() interfaces have been fully retired. Update gethrtime() to use the replacement interface ktime_get_raw_ts64() which was introduced in the 4.18 kernel. Reviewed-by: Tony Hutter <hutter2@llnl.gov> Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov> Closes #10052 Closes #10064
56 lines
1.4 KiB
Plaintext
56 lines
1.4 KiB
Plaintext
dnl #
|
|
dnl # 4.18: ktime_get_coarse_real_ts64() replaces current_kernel_time64().
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_SRC_KTIME_GET_COARSE_REAL_TS64], [
|
|
ZFS_LINUX_TEST_SRC([ktime_get_coarse_real_ts64], [
|
|
#include <linux/mm.h>
|
|
], [
|
|
struct timespec64 ts;
|
|
ktime_get_coarse_real_ts64(&ts);
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_KTIME_GET_COARSE_REAL_TS64], [
|
|
AC_MSG_CHECKING([whether ktime_get_coarse_real_ts64() exists])
|
|
ZFS_LINUX_TEST_RESULT([ktime_get_coarse_real_ts64], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_KTIME_GET_COARSE_REAL_TS64, 1,
|
|
[ktime_get_coarse_real_ts64() exists])
|
|
], [
|
|
AC_MSG_RESULT(no)
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # 4.18: ktime_get_raw_ts64() replaces getrawmonotonic64().
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_SRC_KTIME_GET_RAW_TS64], [
|
|
ZFS_LINUX_TEST_SRC([ktime_get_raw_ts64], [
|
|
#include <linux/mm.h>
|
|
], [
|
|
struct timespec64 ts;
|
|
ktime_get_raw_ts64(&ts);
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_KTIME_GET_RAW_TS64], [
|
|
AC_MSG_CHECKING([whether ktime_get_raw_ts64() exists])
|
|
ZFS_LINUX_TEST_RESULT([ktime_get_raw_ts64], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_KTIME_GET_RAW_TS64, 1,
|
|
[ktime_get_raw_ts64() exists])
|
|
], [
|
|
AC_MSG_RESULT(no)
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_SRC_KTIME], [
|
|
ZFS_AC_KERNEL_SRC_KTIME_GET_COARSE_REAL_TS64
|
|
ZFS_AC_KERNEL_SRC_KTIME_GET_RAW_TS64
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_KTIME], [
|
|
ZFS_AC_KERNEL_KTIME_GET_COARSE_REAL_TS64
|
|
ZFS_AC_KERNEL_KTIME_GET_RAW_TS64
|
|
])
|