mirror of
https://git.proxmox.com/git/mirror_zfs.git
synced 2024-11-17 01:51:00 +03:00
cb2d19010d
Currently only the (FALLOC_FL_PUNCH_HOLE) flag combination is supported, since it's the only one that matches the behavior of zfs_space(). This makes it pretty much useless in its current form, but it's a start. To support other flag combinations we would need to modify zfs_space() to make it more flexible, or emulate the desired functionality in zpl_fallocate(). Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov> Issue #334
49 lines
1.1 KiB
Plaintext
49 lines
1.1 KiB
Plaintext
dnl #
|
|
dnl # Linux 2.6.38 - 3.x API
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_FILE_FALLOCATE], [
|
|
AC_MSG_CHECKING([whether fops->fallocate() exists])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/fs.h>
|
|
],[
|
|
long (*fallocate) (struct file *, int, loff_t, loff_t) = NULL;
|
|
struct file_operations fops __attribute__ ((unused)) = {
|
|
.fallocate = fallocate,
|
|
};
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_FILE_FALLOCATE, 1, [fops->fallocate() exists])
|
|
],[
|
|
AC_MSG_RESULT(no)
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # Linux 2.6.x - 2.6.37 API
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_INODE_FALLOCATE], [
|
|
AC_MSG_CHECKING([whether iops->fallocate() exists])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/fs.h>
|
|
],[
|
|
long (*fallocate) (struct inode *, int, loff_t, loff_t) = NULL;
|
|
struct inode_operations fops __attribute__ ((unused)) = {
|
|
.fallocate = fallocate,
|
|
};
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_INODE_FALLOCATE, 1, [fops->fallocate() exists])
|
|
],[
|
|
AC_MSG_RESULT(no)
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # The fallocate callback was moved from the inode_operations
|
|
dnl # structure to the file_operations structure.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_FALLOCATE], [
|
|
ZFS_AC_KERNEL_FILE_FALLOCATE
|
|
ZFS_AC_KERNEL_INODE_FALLOCATE
|
|
])
|