mirror of
https://git.proxmox.com/git/mirror_zfs.git
synced 2024-12-26 03:09:34 +03:00
608f8749a1
Reduce the time required for ./configure to perform the needed
KABI checks by allowing kbuild to compile multiple test cases in
parallel. This was accomplished by splitting each test's source
code from the logic handling whether that code could be compiled
or not.
By introducing this split it's possible to minimize the number of
times kbuild needs to be invoked. As importantly, it means all of
the tests can be built in parallel. This does require a little extra
care since we expect some tests to fail, so the --keep-going (-k)
option must be provided otherwise some tests may not get compiled.
Furthermore, since a failure during the kbuild modpost phase will
result in an early exit; the final linking phase is limited to tests
which passed the initial compilation and produced an object file.
Once everything has been built the configure script proceeds as
previously. The only significant difference is that it now merely
needs to test for the existence of a .ko file to determine the
result of a given test. This vastly speeds up the entire process.
New test cases should use ZFS_LINUX_TEST_SRC to declare their test
source code and ZFS_LINUX_TEST_RESULT to check the result. All of
the existing kernel-*.m4 files have been updated accordingly, see
config/kernel-current-time.m4 for a basic example. The legacy
ZFS_LINUX_TRY_COMPILE macro has been kept to handle special cases
but it's use is not encouraged.
master (secs) patched (secs)
------------- ----------------
autogen.sh 61 68
configure 137 24 (~17% of current run time)
make -j $(nproc) 44 44
make rpms 287 150
Reviewed-by: Tony Hutter <hutter2@llnl.gov>
Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov>
Closes #8547
Closes #9132
Closes #9341
130 lines
3.4 KiB
Plaintext
130 lines
3.4 KiB
Plaintext
dnl #
|
|
dnl # Handle differences in kernel FPU code.
|
|
dnl #
|
|
dnl # Kernel
|
|
dnl # 5.2: The fpu->initialized flag was replaced by TIF_NEED_FPU_LOAD.
|
|
dnl # HAVE_KERNEL_TIF_NEED_FPU_LOAD
|
|
dnl #
|
|
dnl # 5.0: As an optimization SIMD operations performed by kernel
|
|
dnl # threads can skip saving and restoring their FPU context.
|
|
dnl # Wrappers have been introduced to determine the running
|
|
dnl # context and use either the SIMD or generic implementation.
|
|
dnl # This change was made to the 4.19.38 and 4.14.120 LTS kernels.
|
|
dnl # HAVE_KERNEL_FPU_INITIALIZED
|
|
dnl #
|
|
dnl # 4.2: Use __kernel_fpu_{begin,end}()
|
|
dnl # HAVE_UNDERSCORE_KERNEL_FPU & KERNEL_EXPORTS_X86_FPU
|
|
dnl #
|
|
dnl # Pre-4.2: Use kernel_fpu_{begin,end}()
|
|
dnl # HAVE_KERNEL_FPU & KERNEL_EXPORTS_X86_FPU
|
|
dnl #
|
|
dnl # N.B. The header check is performed before all other checks since it
|
|
dnl # depends on HAVE_KERNEL_FPU_API_HEADER being set in confdefs.h.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_FPU_HEADER], [
|
|
AC_MSG_CHECKING([whether fpu headers are available])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/module.h>
|
|
#include <asm/fpu/api.h>
|
|
],[
|
|
],[
|
|
AC_DEFINE(HAVE_KERNEL_FPU_API_HEADER, 1,
|
|
[kernel has asm/fpu/api.h])
|
|
AC_MSG_RESULT(asm/fpu/api.h)
|
|
],[
|
|
AC_MSG_RESULT(i387.h & xcr.h)
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_SRC_FPU], [
|
|
ZFS_LINUX_TEST_SRC([kernel_fpu], [
|
|
#ifdef HAVE_KERNEL_FPU_API_HEADER
|
|
#include <asm/fpu/api.h>
|
|
#else
|
|
#include <asm/i387.h>
|
|
#include <asm/xcr.h>
|
|
#endif
|
|
], [
|
|
kernel_fpu_begin();
|
|
kernel_fpu_end();
|
|
], [], [$ZFS_META_LICENSE])
|
|
|
|
ZFS_LINUX_TEST_SRC([__kernel_fpu], [
|
|
#ifdef HAVE_KERNEL_FPU_API_HEADER
|
|
#include <asm/fpu/api.h>
|
|
#else
|
|
#include <asm/i387.h>
|
|
#include <asm/xcr.h>
|
|
#endif
|
|
], [
|
|
__kernel_fpu_begin();
|
|
__kernel_fpu_end();
|
|
], [], [$ZFS_META_LICENSE])
|
|
|
|
ZFS_LINUX_TEST_SRC([fpu_initialized], [
|
|
#include <linux/module.h>
|
|
#include <linux/sched.h>
|
|
],[
|
|
struct fpu *fpu = ¤t->thread.fpu;
|
|
if (fpu->initialized) { return (0); };
|
|
])
|
|
|
|
ZFS_LINUX_TEST_SRC([tif_need_fpu_load], [
|
|
#include <linux/module.h>
|
|
#include <asm/thread_info.h>
|
|
|
|
#if !defined(TIF_NEED_FPU_LOAD)
|
|
#error "TIF_NEED_FPU_LOAD undefined"
|
|
#endif
|
|
],[])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_FPU], [
|
|
dnl #
|
|
dnl # Legacy kernel
|
|
dnl #
|
|
AC_MSG_CHECKING([whether kernel fpu is available])
|
|
ZFS_LINUX_TEST_RESULT_SYMBOL([kernel_fpu_license],
|
|
[kernel_fpu_begin], [arch/x86/kernel/fpu/core.c], [
|
|
AC_MSG_RESULT(kernel_fpu_*)
|
|
AC_DEFINE(HAVE_KERNEL_FPU, 1,
|
|
[kernel has kernel_fpu_* functions])
|
|
AC_DEFINE(KERNEL_EXPORTS_X86_FPU, 1,
|
|
[kernel exports FPU functions])
|
|
],[
|
|
dnl #
|
|
dnl # Linux 4.2 kernel
|
|
dnl #
|
|
ZFS_LINUX_TEST_RESULT_SYMBOL([__kernel_fpu_license],
|
|
[__kernel_fpu_begin],
|
|
[arch/x86/kernel/fpu/core.c arch/x86/kernel/i387.c], [
|
|
AC_MSG_RESULT(__kernel_fpu_*)
|
|
AC_DEFINE(HAVE_UNDERSCORE_KERNEL_FPU, 1,
|
|
[kernel has __kernel_fpu_* functions])
|
|
AC_DEFINE(KERNEL_EXPORTS_X86_FPU, 1,
|
|
[kernel exports FPU functions])
|
|
],[
|
|
dnl #
|
|
dnl # Linux 5.0 kernel
|
|
dnl #
|
|
ZFS_LINUX_TEST_RESULT([fpu_initialized], [
|
|
AC_MSG_RESULT(fpu.initialized)
|
|
AC_DEFINE(HAVE_KERNEL_FPU_INITIALIZED, 1,
|
|
[kernel fpu.initialized exists])
|
|
],[
|
|
dnl #
|
|
dnl # Linux 5.2 kernel
|
|
dnl #
|
|
ZFS_LINUX_TEST_RESULT([tif_need_fpu_load], [
|
|
AC_MSG_RESULT(TIF_NEED_FPU_LOAD)
|
|
AC_DEFINE(
|
|
HAVE_KERNEL_TIF_NEED_FPU_LOAD, 1,
|
|
[kernel TIF_NEED_FPU_LOAD exists])
|
|
],[
|
|
AC_MSG_RESULT(unavailable)
|
|
])
|
|
])
|
|
])
|
|
])
|
|
])
|