mirror of
https://git.proxmox.com/git/mirror_zfs.git
synced 2024-12-26 03:09:34 +03:00
4967a3eb9d
The registered xattr .list handler was simplified in the 4.5 kernel
to only perform a permission check. Given a dentry for the file it
must return a boolean indicating if the name is visible. This
differs slightly from the previous APIs which also required the
function to copy the name in to the provided list and return its
size. That is now all the responsibility of the caller.
This should be straight forward change to make to ZoL since we've
always required the caller to make the copy. However, this was
slightly complicated by the need to support 3 older APIs. Yes,
between 2.6.32 and 4.5 there are 4 versions of this interface!
Therefore, while the functional change in this patch is small it
includes significant cleanup to make the code understandable and
maintainable. These changes include:
- Improved configure checks for .list, .get, and .set interfaces.
- Interfaces checked from newest to oldest.
- Strict checking for each possible known interface.
- Configure fails when no known interface is available.
- HAVE_*_XATTR_LIST renamed HAVE_XATTR_LIST_* for consistency
with similar iops and fops configure checks.
- POSIX_ACL_XATTR_{DEFAULT|ACCESS} were removed forcing callers to
move to their replacements, XATTR_NAME_POSIX_ACL_{DEFAULT|ACCESS}.
Compatibility wrapper were added for old kernels.
- ZPL_XATTR_LIST_WRAPPER added which behaves the same as the existing
ZPL_XATTR_{GET|SET} WRAPPERs. Only the inode is guaranteed to be
a valid pointer, passing NULL for the 'list' and 'name' variables
is allowed and must be checked for. All .list functions were
updated to use the wrapper to aid readability.
- zpl_xattr_filldir() updated to use the .list function for its
permission check which is consistent with the updated Linux 4.5
interface. If a .list function is registered it should return 0
to indicate a name should be skipped, if there is no registered
function the name will be added.
- Additional documentation from xattr(7) describing the correct
behavior for each namespace was added before the relevant handlers.
Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov>
Signed-off-by: Tim Chase <tim@chase2k.com>
Signed-off-by: Chunwei Chen <tuxoko@gmail.com>
Issue #4228
318 lines
8.3 KiB
Plaintext
318 lines
8.3 KiB
Plaintext
dnl #
|
|
dnl # 2.6.35 API change,
|
|
dnl # The 'struct xattr_handler' was constified in the generic
|
|
dnl # super_block structure.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_CONST_XATTR_HANDLER], [
|
|
AC_MSG_CHECKING([whether super_block uses const struct xattr_handler])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/fs.h>
|
|
#include <linux/xattr.h>
|
|
|
|
const struct xattr_handler xattr_test_handler = {
|
|
.prefix = "test",
|
|
.get = NULL,
|
|
.set = NULL,
|
|
};
|
|
|
|
const struct xattr_handler *xattr_handlers[] = {
|
|
&xattr_test_handler,
|
|
};
|
|
|
|
const struct super_block sb __attribute__ ((unused)) = {
|
|
.s_xattr = xattr_handlers,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT([yes])
|
|
AC_DEFINE(HAVE_CONST_XATTR_HANDLER, 1,
|
|
[super_block uses const struct xattr_handler])
|
|
],[
|
|
AC_MSG_RESULT([no])
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # Supported xattr handler get() interfaces checked newest to oldest.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_XATTR_HANDLER_GET], [
|
|
dnl #
|
|
dnl # 4.4 API change,
|
|
dnl # The xattr_handler->get() callback was changed to take a
|
|
dnl # attr_handler, and handler_flags argument was removed and
|
|
dnl # should be accessed by handler->flags.
|
|
dnl #
|
|
AC_MSG_CHECKING([whether xattr_handler->get() wants xattr_handler])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/xattr.h>
|
|
|
|
int get(const struct xattr_handler *handler,
|
|
struct dentry *dentry, const char *name,
|
|
void *buffer, size_t size) { return 0; }
|
|
static const struct xattr_handler
|
|
xops __attribute__ ((unused)) = {
|
|
.get = get,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XATTR_GET_HANDLER, 1,
|
|
[xattr_handler->get() wants xattr_handler])
|
|
],[
|
|
dnl #
|
|
dnl # 2.6.33 API change,
|
|
dnl # The xattr_handler->get() callback was changed to take
|
|
dnl # a dentry instead of an inode, and a handler_flags
|
|
dnl # argument was added.
|
|
dnl #
|
|
AC_MSG_RESULT(no)
|
|
AC_MSG_CHECKING([whether xattr_handler->get() wants dentry])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/xattr.h>
|
|
|
|
int get(struct dentry *dentry, const char *name,
|
|
void *buffer, size_t size, int handler_flags)
|
|
{ return 0; }
|
|
static const struct xattr_handler
|
|
xops __attribute__ ((unused)) = {
|
|
.get = get,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XATTR_GET_DENTRY, 1,
|
|
[xattr_handler->get() wants dentry])
|
|
],[
|
|
dnl #
|
|
dnl # 2.6.32 API
|
|
dnl #
|
|
AC_MSG_RESULT(no)
|
|
AC_MSG_CHECKING(
|
|
[whether xattr_handler->get() wants inode])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/xattr.h>
|
|
|
|
int get(struct inode *ip, const char *name,
|
|
void *buffer, size_t size) { return 0; }
|
|
static const struct xattr_handler
|
|
xops __attribute__ ((unused)) = {
|
|
.get = get,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XATTR_GET_INODE, 1,
|
|
[xattr_handler->get() wants inode])
|
|
],[
|
|
AC_MSG_ERROR([no; please file a bug report])
|
|
])
|
|
])
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # Supported xattr handler set() interfaces checked newest to oldest.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_XATTR_HANDLER_SET], [
|
|
dnl #
|
|
dnl # 4.4 API change,
|
|
dnl # The xattr_handler->set() callback was changed to take a
|
|
dnl # xattr_handler, and handler_flags argument was removed and
|
|
dnl # should be accessed by handler->flags.
|
|
dnl #
|
|
AC_MSG_CHECKING([whether xattr_handler->set() wants xattr_handler])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/xattr.h>
|
|
|
|
int set(const struct xattr_handler *handler,
|
|
struct dentry *dentry, const char *name,
|
|
const void *buffer, size_t size, int flags)
|
|
{ return 0; }
|
|
static const struct xattr_handler
|
|
xops __attribute__ ((unused)) = {
|
|
.set = set,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XATTR_SET_HANDLER, 1,
|
|
[xattr_handler->set() wants xattr_handler])
|
|
],[
|
|
dnl #
|
|
dnl # 2.6.33 API change,
|
|
dnl # The xattr_handler->set() callback was changed to take a
|
|
dnl # dentry instead of an inode, and a handler_flags
|
|
dnl # argument was added.
|
|
dnl #
|
|
AC_MSG_RESULT(no)
|
|
AC_MSG_CHECKING([whether xattr_handler->set() wants dentry])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/xattr.h>
|
|
|
|
int set(struct dentry *dentry, const char *name,
|
|
const void *buffer, size_t size, int flags,
|
|
int handler_flags) { return 0; }
|
|
static const struct xattr_handler
|
|
xops __attribute__ ((unused)) = {
|
|
.set = set,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XATTR_SET_DENTRY, 1,
|
|
[xattr_handler->set() wants dentry])
|
|
],[
|
|
dnl #
|
|
dnl # 2.6.32 API
|
|
dnl #
|
|
AC_MSG_RESULT(no)
|
|
AC_MSG_CHECKING(
|
|
[whether xattr_handler->set() wants inode])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/xattr.h>
|
|
|
|
int set(struct inode *ip, const char *name,
|
|
const void *buffer, size_t size, int flags)
|
|
{ return 0; }
|
|
static const struct xattr_handler
|
|
xops __attribute__ ((unused)) = {
|
|
.set = set,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XATTR_SET_INODE, 1,
|
|
[xattr_handler->set() wants inode])
|
|
],[
|
|
AC_MSG_ERROR([no; please file a bug report])
|
|
])
|
|
])
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # Supported xattr handler list() interfaces checked newest to oldest.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_XATTR_HANDLER_LIST], [
|
|
dnl # 4.5 API change,
|
|
dnl # The xattr_handler->list() callback was changed to take only a
|
|
dnl # dentry and it only needs to return if it's accessable.
|
|
AC_MSG_CHECKING([whether xattr_handler->list() wants simple])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/xattr.h>
|
|
|
|
bool list(struct dentry *dentry) { return 0; }
|
|
static const struct xattr_handler
|
|
xops __attribute__ ((unused)) = {
|
|
.list = list,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XATTR_LIST_SIMPLE, 1,
|
|
[xattr_handler->list() wants simple])
|
|
],[
|
|
dnl #
|
|
dnl # 4.4 API change,
|
|
dnl # The xattr_handler->list() callback was changed to take a
|
|
dnl # xattr_handler, and handler_flags argument was removed
|
|
dnl # and should be accessed by handler->flags.
|
|
dnl #
|
|
AC_MSG_RESULT(no)
|
|
AC_MSG_CHECKING(
|
|
[whether xattr_handler->list() wants xattr_handler])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/xattr.h>
|
|
|
|
size_t list(const struct xattr_handler *handler,
|
|
struct dentry *dentry, char *list, size_t list_size,
|
|
const char *name, size_t name_len) { return 0; }
|
|
static const struct xattr_handler
|
|
xops __attribute__ ((unused)) = {
|
|
.list = list,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XATTR_LIST_HANDLER, 1,
|
|
[xattr_handler->list() wants xattr_handler])
|
|
],[
|
|
dnl #
|
|
dnl # 2.6.33 API change,
|
|
dnl # The xattr_handler->list() callback was changed
|
|
dnl # to take a dentry instead of an inode, and a
|
|
dnl # handler_flags argument was added.
|
|
dnl #
|
|
AC_MSG_RESULT(no)
|
|
AC_MSG_CHECKING(
|
|
[whether xattr_handler->list() wants dentry])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/xattr.h>
|
|
|
|
size_t list(struct dentry *dentry,
|
|
char *list, size_t list_size,
|
|
const char *name, size_t name_len,
|
|
int handler_flags) { return 0; }
|
|
static const struct xattr_handler
|
|
xops __attribute__ ((unused)) = {
|
|
.list = list,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XATTR_LIST_DENTRY, 1,
|
|
[xattr_handler->list() wants dentry])
|
|
],[
|
|
dnl #
|
|
dnl # 2.6.32 API
|
|
dnl #
|
|
AC_MSG_RESULT(no)
|
|
AC_MSG_CHECKING(
|
|
[whether xattr_handler->list() wants inode])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/xattr.h>
|
|
|
|
size_t list(struct inode *ip, char *lst,
|
|
size_t list_size, const char *name,
|
|
size_t name_len) { return 0; }
|
|
static const struct xattr_handler
|
|
xops __attribute__ ((unused)) = {
|
|
.list = list,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_XATTR_LIST_INODE, 1,
|
|
[xattr_handler->list() wants inode])
|
|
],[
|
|
AC_MSG_ERROR(
|
|
[no; please file a bug report])
|
|
])
|
|
])
|
|
])
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # 3.7 API change,
|
|
dnl # The posix_acl_{from,to}_xattr functions gained a new
|
|
dnl # parameter: user_ns
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS], [
|
|
AC_MSG_CHECKING([whether posix_acl_from_xattr() needs user_ns])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/cred.h>
|
|
#include <linux/fs.h>
|
|
#include <linux/posix_acl_xattr.h>
|
|
],[
|
|
posix_acl_from_xattr(&init_user_ns, NULL, 0);
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_POSIX_ACL_FROM_XATTR_USERNS, 1,
|
|
[posix_acl_from_xattr() needs user_ns])
|
|
],[
|
|
AC_MSG_RESULT(no)
|
|
])
|
|
])
|
|
|