mirror of
https://git.proxmox.com/git/mirror_zfs.git
synced 2024-12-27 11:29:36 +03:00
96b0785f52
As far as I can tell, this never made it to a real release. It was
introduced in 6b2553918d8b and removed a couple of weeks later in
fceef393a538. This was all part of the development of what would become
4.5. So I assume this was OpenZFS chasing upstream development at the
time.
fceef393a538 viro 2015-12-30 switch ->get_link() to delayed_call, kill ->put_link()
cd3417c8fc95 viro 2015-12-29 kill free_page_put_link()
0d0def49d05a viro 2015-12-08 teach nfs_get_link() to work in RCU mode
1a384eaac265 viro 2015-12-08 teach proc_self_get_link()/proc_thread_self_get_link() to work in RCU mode
6a6c99049635 viro 2015-12-08 teach shmem_get_link() to work in RCU mode
d3883d4f9344 viro 2015-12-08 teach page_get_link() to work in RCU mode
6b2553918d8b viro 2015-12-08 replace ->follow_link() with new method that could stay in RCU mode
Sponsored-by: https://despairlabs.com/sponsor/
Reviewed-by: Brian Behlendorf <behlendorf1@llnl.gov>
Reviewed-by: Tony Hutter <hutter2@llnl.gov>
Reviewed-by: Tino Reichardt <milky-zfs@mcmilk.de>
Signed-off-by: Rob Norris <robn@despairlabs.com>
Closes #16479
56 lines
1.5 KiB
Plaintext
56 lines
1.5 KiB
Plaintext
dnl #
|
|
dnl # Supported get_link() interfaces checked newest to oldest.
|
|
dnl # Note this interface used to be named follow_link.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_SRC_GET_LINK], [
|
|
ZFS_LINUX_TEST_SRC([inode_operations_get_link], [
|
|
#include <linux/fs.h>
|
|
static const char *get_link(struct dentry *de, struct inode *ip,
|
|
struct delayed_call *done) { return "symlink"; }
|
|
static struct inode_operations
|
|
iops __attribute__ ((unused)) = {
|
|
.get_link = get_link,
|
|
};
|
|
],[])
|
|
|
|
ZFS_LINUX_TEST_SRC([inode_operations_follow_link], [
|
|
#include <linux/fs.h>
|
|
static const char *follow_link(struct dentry *de,
|
|
void **cookie) { return "symlink"; }
|
|
static struct inode_operations
|
|
iops __attribute__ ((unused)) = {
|
|
.follow_link = follow_link,
|
|
};
|
|
],[])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_GET_LINK], [
|
|
dnl #
|
|
dnl # 4.5 API change
|
|
dnl # The get_link interface has added a delayed done call and
|
|
dnl # used it to retire the put_link() interface.
|
|
dnl #
|
|
AC_MSG_CHECKING([whether iops->get_link() passes delayed])
|
|
ZFS_LINUX_TEST_RESULT([inode_operations_get_link], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_GET_LINK_DELAYED, 1, [iops->get_link() delayed])
|
|
],[
|
|
AC_MSG_RESULT(no)
|
|
|
|
dnl #
|
|
dnl # 4.2 API change
|
|
dnl # This kernel retired the nameidata structure.
|
|
dnl #
|
|
AC_MSG_CHECKING(
|
|
[whether iops->follow_link() passes cookie])
|
|
ZFS_LINUX_TEST_RESULT([inode_operations_follow_link], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_FOLLOW_LINK_COOKIE, 1,
|
|
[iops->follow_link() cookie])
|
|
],[
|
|
AC_MSG_RESULT(no)
|
|
ZFS_LINUX_TEST_ERROR([get_link])
|
|
])
|
|
])
|
|
])
|