mirror of
https://git.proxmox.com/git/mirror_zfs.git
synced 2024-11-17 10:01:01 +03:00
e5db313494
Restore the SIMD optimization for 4.19.38 LTS, 4.14.120 LTS,
and 5.0 and newer kernels. This is accomplished by leveraging
the fact that by definition dedicated kernel threads never need
to concern themselves with saving and restoring the user FPU state.
Therefore, they may use the FPU as long as we can guarantee user
tasks always restore their FPU state before context switching back
to user space.
For the 5.0 and 5.1 kernels disabling preemption and local
interrupts is sufficient to allow the FPU to be used. All non-kernel
threads will restore the preserved user FPU state.
For 5.2 and latter kernels the user FPU state restoration will be
skipped if the kernel determines the registers have not changed.
Therefore, for these kernels we need to perform the additional
step of saving and restoring the FPU registers. Invalidating the
per-cpu global tracking the FPU state would force a restore but
that functionality is private to the core x86 FPU implementation
and unavailable.
In practice, restricting SIMD to kernel threads is not a major
restriction for ZFS. The vast majority of SIMD operations are
already performed by the IO pipeline. The remaining cases are
relatively infrequent and can be handled by the generic code
without significant impact. The two most noteworthy cases are:
1) Decrypting the wrapping key for an encrypted dataset,
i.e. `zfs load-key`. All other encryption and decryption
operations will use the SIMD optimized implementations.
2) Generating the payload checksums for a `zfs send` stream.
In order to avoid making any changes to the higher layers of ZFS
all of the `*_get_ops()` functions were updated to take in to
consideration the calling context. This allows for the fastest
implementation to be used as appropriate (see kfpu_allowed()).
The only other notable instance of SIMD operations being used
outside a kernel thread was at module load time. This code
was moved in to a taskq in order to accommodate the new kernel
thread restriction.
Finally, a few other modifications were made in order to further
harden this code and facilitate testing. They include updating
each implementations operations structure to be declared as a
constant. And allowing "cycle" to be set when selecting the
preferred ops in the kernel as well as user space.
Reviewed-by: Tony Hutter <hutter2@llnl.gov>
Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov>
Closes #8754
Closes #8793
Closes #8965
102 lines
2.9 KiB
Plaintext
102 lines
2.9 KiB
Plaintext
dnl #
|
|
dnl # Handle differences in kernel FPU code.
|
|
dnl #
|
|
dnl # Kernel
|
|
dnl # 5.2: The fpu->initialized flag was replaced by TIF_NEED_FPU_LOAD.
|
|
dnl # HAVE_KERNEL_TIF_NEED_FPU_LOAD
|
|
dnl #
|
|
dnl # 5.0: As an optimization SIMD operations performed by kernel
|
|
dnl # threads can skip saving and restoring their FPU context.
|
|
dnl # Wrappers have been introduced to determine the running
|
|
dnl # context and use either the SIMD or generic implementation.
|
|
dnl # This change was made to the 4.19.38 and 4.14.120 LTS kernels.
|
|
dnl # HAVE_KERNEL_FPU_INITIALIZED
|
|
dnl #
|
|
dnl # 4.2: Use __kernel_fpu_{begin,end}()
|
|
dnl # HAVE_UNDERSCORE_KERNEL_FPU & KERNEL_EXPORTS_X86_FPU
|
|
dnl #
|
|
dnl # Pre-4.2: Use kernel_fpu_{begin,end}()
|
|
dnl # HAVE_KERNEL_FPU & KERNEL_EXPORTS_X86_FPU
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_FPU], [
|
|
AC_MSG_CHECKING([which kernel_fpu header to use])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/module.h>
|
|
#include <asm/fpu/api.h>
|
|
],[
|
|
],[
|
|
AC_DEFINE(HAVE_KERNEL_FPU_API_HEADER, 1, [kernel has asm/fpu/api.h])
|
|
AC_MSG_RESULT(asm/fpu/api.h)
|
|
],[
|
|
AC_MSG_RESULT(i387.h & xcr.h)
|
|
])
|
|
|
|
AC_MSG_CHECKING([which kernel_fpu function to use])
|
|
ZFS_LINUX_TRY_COMPILE_SYMBOL([
|
|
#include <linux/module.h>
|
|
#ifdef HAVE_KERNEL_FPU_API_HEADER
|
|
#include <asm/fpu/api.h>
|
|
#else
|
|
#include <asm/i387.h>
|
|
#include <asm/xcr.h>
|
|
#endif
|
|
MODULE_LICENSE("$ZFS_META_LICENSE");
|
|
],[
|
|
kernel_fpu_begin();
|
|
kernel_fpu_end();
|
|
], [kernel_fpu_begin], [arch/x86/kernel/fpu/core.c], [
|
|
AC_MSG_RESULT(kernel_fpu_*)
|
|
AC_DEFINE(HAVE_KERNEL_FPU, 1, [kernel has kernel_fpu_* functions])
|
|
AC_DEFINE(KERNEL_EXPORTS_X86_FPU, 1, [kernel exports FPU functions])
|
|
],[
|
|
ZFS_LINUX_TRY_COMPILE_SYMBOL([
|
|
#include <linux/module.h>
|
|
#ifdef HAVE_KERNEL_FPU_API_HEADER
|
|
#include <asm/fpu/api.h>
|
|
#else
|
|
#include <asm/i387.h>
|
|
#include <asm/xcr.h>
|
|
#endif
|
|
MODULE_LICENSE("$ZFS_META_LICENSE");
|
|
],[
|
|
__kernel_fpu_begin();
|
|
__kernel_fpu_end();
|
|
], [__kernel_fpu_begin], [arch/x86/kernel/fpu/core.c arch/x86/kernel/i387.c], [
|
|
AC_MSG_RESULT(__kernel_fpu_*)
|
|
AC_DEFINE(HAVE_UNDERSCORE_KERNEL_FPU, 1,
|
|
[kernel has __kernel_fpu_* functions])
|
|
AC_DEFINE(KERNEL_EXPORTS_X86_FPU, 1,
|
|
[kernel exports FPU functions])
|
|
],[
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/module.h>
|
|
#include <linux/sched.h>
|
|
],[
|
|
struct fpu *fpu = ¤t->thread.fpu;
|
|
if (fpu->initialized) { return (0); };
|
|
],[
|
|
AC_MSG_RESULT(fpu.initialized)
|
|
AC_DEFINE(HAVE_KERNEL_FPU_INITIALIZED, 1,
|
|
[kernel fpu.initialized exists])
|
|
],[
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/module.h>
|
|
#include <asm/thread_info.h>
|
|
|
|
#if !defined(TIF_NEED_FPU_LOAD)
|
|
#error "TIF_NEED_FPU_LOAD undefined"
|
|
#endif
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT(TIF_NEED_FPU_LOAD)
|
|
AC_DEFINE(
|
|
HAVE_KERNEL_TIF_NEED_FPU_LOAD, 1,
|
|
[kernel TIF_NEED_FPU_LOAD exists])
|
|
],[
|
|
AC_MSG_RESULT(unavailable)
|
|
])
|
|
])
|
|
])
|
|
])
|
|
])
|