mirror of
https://git.proxmox.com/git/mirror_zfs.git
synced 2025-10-26 18:05:04 +03:00
b9c59ec83a
As of GCC 4.6, specific kernel 2.6.32 header files do not compile cleanly without warnings. One specific example of this is the arch/x86/include/asm/percpu.h file. Thus, a few of the configure tests were getting hung up on this and the '-Wno-unsued-but-set-variables' compile option had to be introduced. Signed-off-by: Prakash Surya <surya1@llnl.gov> Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov> Closes #459
42 lines
1.1 KiB
Plaintext
42 lines
1.1 KiB
Plaintext
dnl #
|
|
dnl # 2.6.29 API change
|
|
dnl # In the 2.6.29 kernel blk_rq_bytes() was available as a GPL-only symbol.
|
|
dnl # So we need to check the symbol license as well. As of 2.6.31 the
|
|
dnl blk_rq_bytes() helper was changed to a static inline which we can use.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_BLK_RQ_BYTES], [
|
|
AC_MSG_CHECKING([whether blk_rq_bytes() is available])
|
|
tmp_flags="$EXTRA_KCFLAGS"
|
|
EXTRA_KCFLAGS="-Wno-unused-but-set-variable"
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/blkdev.h>
|
|
],[
|
|
struct request *req = NULL;
|
|
(void) blk_rq_bytes(req);
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_BLK_RQ_BYTES, 1,
|
|
[blk_rq_bytes() is available])
|
|
],[
|
|
AC_MSG_RESULT(no)
|
|
])
|
|
|
|
AC_MSG_CHECKING([whether blk_rq_bytes() is GPL-only])
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/module.h>
|
|
#include <linux/blkdev.h>
|
|
|
|
MODULE_LICENSE("CDDL");
|
|
],[
|
|
struct request *req = NULL;
|
|
(void) blk_rq_bytes(req);
|
|
],[
|
|
AC_MSG_RESULT(no)
|
|
],[
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_BLK_RQ_BYTES_GPL_ONLY, 1,
|
|
[blk_rq_bytes() is GPL-only])
|
|
])
|
|
EXTRA_KCFLAGS="$tmp_flags"
|
|
])
|