mirror of
https://git.proxmox.com/git/mirror_zfs.git
synced 2024-11-17 10:01:01 +03:00
b9c59ec83a
As of GCC 4.6, specific kernel 2.6.32 header files do not compile cleanly without warnings. One specific example of this is the arch/x86/include/asm/percpu.h file. Thus, a few of the configure tests were getting hung up on this and the '-Wno-unsued-but-set-variables' compile option had to be introduced. Signed-off-by: Prakash Surya <surya1@llnl.gov> Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov> Closes #459
37 lines
1.1 KiB
Plaintext
37 lines
1.1 KiB
Plaintext
dnl #
|
|
dnl # 2.6.x API change
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS], [
|
|
AC_MSG_CHECKING([block device operation prototypes])
|
|
tmp_flags="$EXTRA_KCFLAGS"
|
|
EXTRA_KCFLAGS="-Wno-unused-but-set-variable"
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/blkdev.h>
|
|
],[
|
|
int (*blk_open) (struct block_device *, fmode_t) = NULL;
|
|
int (*blk_release) (struct gendisk *, fmode_t) = NULL;
|
|
int (*blk_ioctl) (struct block_device *, fmode_t,
|
|
unsigned, unsigned long) = NULL;
|
|
int (*blk_compat_ioctl) (struct block_device *, fmode_t,
|
|
unsigned, unsigned long) = NULL;
|
|
struct block_device_operations blk_ops = {
|
|
.open = blk_open,
|
|
.release = blk_release,
|
|
.ioctl = blk_ioctl,
|
|
.compat_ioctl = blk_compat_ioctl,
|
|
};
|
|
|
|
blk_ops.open(NULL, 0);
|
|
blk_ops.release(NULL, 0);
|
|
blk_ops.ioctl(NULL, 0, 0, 0);
|
|
blk_ops.compat_ioctl(NULL, 0, 0, 0);
|
|
],[
|
|
AC_MSG_RESULT(struct block_device)
|
|
AC_DEFINE(HAVE_BDEV_BLOCK_DEVICE_OPERATIONS, 1,
|
|
[struct block_device_operations use bdevs])
|
|
],[
|
|
AC_MSG_RESULT(struct inode)
|
|
])
|
|
EXTRA_KCFLAGS="$tmp_flags"
|
|
])
|