mirror of
https://git.proxmox.com/git/mirror_zfs.git
synced 2024-11-18 02:20:59 +03:00
fb7aa3c9b2
Several m4 macros have been retired in autoconf 2.70. Update the the build system to use the new macros provided to replace them. * Replaced AC_HELP_STRING with AS_HELP_STRING. * Replaced AC_TRY_COMPILE with AC_COMPILE_IFELSE/AC_LANG_PROGRAM. * Replaced AC_CANONICAL_SYSTEM with AC_CANONICAL_TARGET * Replaced AC_PROG_LIBTOOL with LT_INIT * $CPP is not defined in ZFS_AC_KERNEL and really shouldn't be directly used like this. Replace it with an $AWK command to extract the kernel source version. Reviewed-by: Eli Schwartz <eschwartz@archlinux.org> Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov> Issue #11413 Closes #11419
54 lines
1.9 KiB
Plaintext
54 lines
1.9 KiB
Plaintext
AC_DEFUN([ZFS_AC_CONFIG_USER_SYSTEMD], [
|
|
AC_ARG_ENABLE(systemd,
|
|
AS_HELP_STRING([--enable-systemd],
|
|
[install systemd unit/preset files [[default: yes]]]),
|
|
[enable_systemd=$enableval],
|
|
[enable_systemd=check])
|
|
|
|
AC_ARG_WITH(systemdunitdir,
|
|
AS_HELP_STRING([--with-systemdunitdir=DIR],
|
|
[install systemd unit files in dir [[/usr/lib/systemd/system]]]),
|
|
systemdunitdir=$withval,systemdunitdir=/usr/lib/systemd/system)
|
|
|
|
AC_ARG_WITH(systemdpresetdir,
|
|
AS_HELP_STRING([--with-systemdpresetdir=DIR],
|
|
[install systemd preset files in dir [[/usr/lib/systemd/system-preset]]]),
|
|
systemdpresetdir=$withval,systemdpresetdir=/usr/lib/systemd/system-preset)
|
|
|
|
AC_ARG_WITH(systemdmodulesloaddir,
|
|
AS_HELP_STRING([--with-systemdmodulesloaddir=DIR],
|
|
[install systemd module load files into dir [[/usr/lib/modules-load.d]]]),
|
|
systemdmodulesloaddir=$withval,systemdmodulesloaddir=/usr/lib/modules-load.d)
|
|
|
|
AC_ARG_WITH(systemdgeneratordir,
|
|
AS_HELP_STRING([--with-systemdgeneratordir=DIR],
|
|
[install systemd generators in dir [[/usr/lib/systemd/system-generators]]]),
|
|
systemdgeneratordir=$withval,systemdgeneratordir=/usr/lib/systemd/system-generators)
|
|
|
|
AS_IF([test "x$enable_systemd" = xcheck], [
|
|
AS_IF([systemctl --version >/dev/null 2>&1],
|
|
[enable_systemd=yes],
|
|
[enable_systemd=no])
|
|
])
|
|
|
|
AC_MSG_CHECKING(for systemd support)
|
|
AC_MSG_RESULT([$enable_systemd])
|
|
|
|
AS_IF([test "x$enable_systemd" = xyes], [
|
|
ZFS_INIT_SYSTEMD=systemd
|
|
ZFS_MODULE_LOAD=modules-load.d
|
|
DEFINE_SYSTEMD='--with systemd --define "_unitdir $(systemdunitdir)" --define "_presetdir $(systemdpresetdir)" --define "_generatordir $(systemdgeneratordir)"'
|
|
modulesloaddir=$systemdmodulesloaddir
|
|
],[
|
|
DEFINE_SYSTEMD='--without systemd'
|
|
])
|
|
|
|
AC_SUBST(ZFS_INIT_SYSTEMD)
|
|
AC_SUBST(ZFS_MODULE_LOAD)
|
|
AC_SUBST(DEFINE_SYSTEMD)
|
|
AC_SUBST(systemdunitdir)
|
|
AC_SUBST(systemdpresetdir)
|
|
AC_SUBST(systemdgeneratordir)
|
|
AC_SUBST(modulesloaddir)
|
|
])
|