mirror of
https://git.proxmox.com/git/mirror_zfs.git
synced 2024-11-17 18:11:00 +03:00
f269060a24
The previous autoconf test for the presence of super_setup_bdi_name() uses an invocation with an incorrect type signature, producing a warning by the compiler when the test is run. This gets elevated to an error when compiling with -Werror=format-security, causing autoconf to falsely infer super_setup_bdi_name() is not present. This updates the testing code to match the invocation used in include/linux/vfs_compat.h. Reviewed-by: loli10K <ezomori.nozomu@gmail.com> Reviewed-by: Brian Behlendorf <behlendorf1@llnl.gov> Signed-off-by: Justin Bedo <cu@cua0.org> Closes #6398
58 lines
1.8 KiB
Plaintext
58 lines
1.8 KiB
Plaintext
dnl #
|
|
dnl # 2.6.32 - 2.6.33, bdi_setup_and_register() is not exported.
|
|
dnl # 2.6.34 - 3.19, bdi_setup_and_register() takes 3 arguments.
|
|
dnl # 4.0 - 4.11, bdi_setup_and_register() takes 2 arguments.
|
|
dnl # 4.12 - x.y, super_setup_bdi_name() new interface.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_BDI], [
|
|
AC_MSG_CHECKING([whether super_setup_bdi_name() exists])
|
|
ZFS_LINUX_TRY_COMPILE_SYMBOL([
|
|
#include <linux/fs.h>
|
|
struct super_block sb;
|
|
], [
|
|
char *name = "bdi";
|
|
atomic_long_t zfs_bdi_seq;
|
|
int error __attribute__((unused)) =
|
|
super_setup_bdi_name(&sb, "%.28s-%ld", name, atomic_long_inc_return(&zfs_bdi_seq));
|
|
], [super_setup_bdi_name], [fs/super.c], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_SUPER_SETUP_BDI_NAME, 1,
|
|
[super_setup_bdi_name() exits])
|
|
], [
|
|
AC_MSG_RESULT(no)
|
|
AC_MSG_CHECKING(
|
|
[whether bdi_setup_and_register() wants 2 args])
|
|
ZFS_LINUX_TRY_COMPILE_SYMBOL([
|
|
#include <linux/backing-dev.h>
|
|
struct backing_dev_info bdi;
|
|
], [
|
|
char *name = "bdi";
|
|
int error __attribute__((unused)) =
|
|
bdi_setup_and_register(&bdi, name);
|
|
], [bdi_setup_and_register], [mm/backing-dev.c], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_2ARGS_BDI_SETUP_AND_REGISTER, 1,
|
|
[bdi_setup_and_register() wants 2 args])
|
|
], [
|
|
AC_MSG_RESULT(no)
|
|
AC_MSG_CHECKING(
|
|
[whether bdi_setup_and_register() wants 3 args])
|
|
ZFS_LINUX_TRY_COMPILE_SYMBOL([
|
|
#include <linux/backing-dev.h>
|
|
struct backing_dev_info bdi;
|
|
], [
|
|
char *name = "bdi";
|
|
unsigned int cap = BDI_CAP_MAP_COPY;
|
|
int error __attribute__((unused)) =
|
|
bdi_setup_and_register(&bdi, name, cap);
|
|
], [bdi_setup_and_register], [mm/backing-dev.c], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_3ARGS_BDI_SETUP_AND_REGISTER, 1,
|
|
[bdi_setup_and_register() wants 3 args])
|
|
], [
|
|
AC_MSG_RESULT(no)
|
|
])
|
|
])
|
|
])
|
|
])
|