mirror of
https://git.proxmox.com/git/mirror_zfs.git
synced 2025-10-26 18:05:04 +03:00
865ca576ab
Sponsored-by: https://despairlabs.com/sponsor/ Signed-off-by: Rob Norris <robn@despairlabs.com> Reviewed-by: Tony Hutter <hutter2@llnl.gov> Reviewed-by: Brian Behlendorf <behlendorf1@llnl.gov>
88 lines
2.4 KiB
ArmAsm
88 lines
2.4 KiB
ArmAsm
// SPDX-License-Identifier: BSD-2-Clause
|
|
/*-
|
|
* Copyright (c) 2014 Andrew Turner
|
|
* Copyright (c) 2014-2015 The FreeBSD Foundation
|
|
* All rights reserved.
|
|
*
|
|
* Portions of this software were developed by Andrew Turner
|
|
* under sponsorship from the FreeBSD Foundation
|
|
*
|
|
* Redistribution and use in source and binary forms, with or without
|
|
* modification, are permitted provided that the following conditions
|
|
* are met:
|
|
* 1. Redistributions of source code must retain the above copyright
|
|
* notice, this list of conditions and the following disclaimer.
|
|
* 2. Redistributions in binary form must reproduce the above copyright
|
|
* notice, this list of conditions and the following disclaimer in the
|
|
* documentation and/or other materials provided with the distribution.
|
|
*
|
|
* THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
|
|
* ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
|
|
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
|
|
* ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
|
|
* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
|
|
* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
|
|
* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
|
|
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
|
|
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
|
|
* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
|
|
* SUCH DAMAGE.
|
|
*
|
|
*/
|
|
|
|
|
|
#ifdef __aarch64__
|
|
|
|
#define ENTRY(sym) \
|
|
.text; \
|
|
.globl sym; \
|
|
.balign 2; \
|
|
.type sym,#function; \
|
|
sym:
|
|
|
|
#define END(sym) \
|
|
.size sym, . - sym
|
|
|
|
|
|
ENTRY(setjmp)
|
|
/* Store the stack pointer */
|
|
mov x8, sp
|
|
str x8, [x0], #8
|
|
|
|
/* Store the general purpose registers and lr */
|
|
stp x19, x20, [x0], #16
|
|
stp x21, x22, [x0], #16
|
|
stp x23, x24, [x0], #16
|
|
stp x25, x26, [x0], #16
|
|
stp x27, x28, [x0], #16
|
|
stp x29, x30, [x0], #16
|
|
|
|
/* Return value */
|
|
mov x0, #0
|
|
ret
|
|
END(setjmp)
|
|
|
|
ENTRY(longjmp)
|
|
/* Restore the stack pointer */
|
|
ldr x8, [x0], #8
|
|
mov sp, x8
|
|
|
|
/* Restore the general purpose registers and lr */
|
|
ldp x19, x20, [x0], #16
|
|
ldp x21, x22, [x0], #16
|
|
ldp x23, x24, [x0], #16
|
|
ldp x25, x26, [x0], #16
|
|
ldp x27, x28, [x0], #16
|
|
ldp x29, x30, [x0], #16
|
|
|
|
/* Load the return value */
|
|
mov x0, x1
|
|
ret
|
|
END(longjmp)
|
|
|
|
#ifdef __ELF__
|
|
.section .note.GNU-stack,"",%progbits
|
|
#endif
|
|
|
|
#endif /* __aarch64__ */
|